Inviare email con allegato pdf esterno

gfrullo

il 03 feb 2019, 10:02

14 risposte

gfrullo

Pochi posts

Iscritto da: apr, 2018

Messaggi:: 16

Inviare email con allegato pdf esterno

03 feb 2019, 10:51

Ho l'esigenza di allegare un file in formato pdf ad una mail partendo da una maschera
Il path del file è il valore di un campo della maschera (nomefilerda) , di tipo testo.

Con il codice seguente, che attivo con doppio click su pulsante, mi prepara correttamente la mail ma non mi allega il file.

Private Sub Descrizione_DblClick(Cancel As Integer)
DoCmd.SetWarnings False
   Dim NC As String
   NC = Forms![rda_approval]![nomefilerda].Value 'con NC nome del campo NOMEFILERDA
   DoCmd.SendObject acSendNoObject, NC, , "TO","CC", "", NC, "Invio RDA APPROVED Servizi Commessa generato automaticamente"
End Sub

dove commetto errori? forse Do.Cmd.SendObject non si può usare con oggetti non interni al database?

14 Risposte

@Alex
Super Famoso
Iscritto da
feb, 2012
Messaggi:
8752
Re: Inviare email con allegato pdf esterno
03 feb 2019, 11:26
Se stampi un report in PDF puoi inviarlo... ma se vuoi inviare mail con allegato esterno... no devi usare librerie specifiche come Outlook o MAPI o CDO.
M
MARMAURO
Utente Attivo
Iscritto da
gen, 2019
Messaggi:
149
Re: Inviare email con allegato pdf esterno
03 feb 2019, 11:43
gfrullo ha scritto:
Ho l'esigenza di allegare un file in formato pdf ad una mail partendo da una maschera
Il path del file è il valore di un campo della maschera (nomefilerda) , di tipo testo.

Con il codice seguente, che attivo con doppio click su pulsante, mi prepara correttamente la mail ma non mi allega il file.

Private Sub Descrizione_DblClick(Cancel As Integer) DoCmd.SetWarnings False Dim NC As String NC = Forms![rda_approval]![nomefilerda].Value 'con NC nome del campo NOMEFILERDA DoCmd.SendObject acSendNoObject, NC, , "TO","CC", "", NC, "Invio RDA APPROVED Servizi Commessa generato automaticamente" End Sub
dove commetto errori? forse Do.Cmd.SendObject non si può usare con oggetti non interni al database?
suggerimento
```
.Attachments.Add 
```
@Alex
Super Famoso
Iscritto da
feb, 2012
Messaggi:
8752
Re: Inviare email con allegato pdf esterno
03 feb 2019, 13:04
MARMAURO ha scritto:
suggerimento
.Attachments.Add
Che suggerimento sarebbe questo...?
Convieni che nessun oggetto nativo di Access esponga quella Collection né quel metodo Add...?
Sicché conviene dare suggerimenti più adeguati indica la Libreria almeno a cui ti riferisci con l'istanza principale dell'oggetto... altrimenti cos sai capisce...?
M
MARMAURO
Utente Attivo
Iscritto da
gen, 2019
Messaggi:
149
Re: Inviare email con allegato pdf esterno
03 feb 2019, 13:18
@Alex ha scritto:

MARMAURO ha scritto:
suggerimento
.Attachments.Add

Che suggerimento sarebbe questo...?
Convieni che nessun oggetto nativo di Access esponga quella Collection né quel metodo Add...?
Sicché conviene dare suggerimenti più adeguati indica la Libreria almeno a cui ti riferisci con l'istanza principale dell'oggetto... altrimenti cos sai capisce...?
meglio così ? o troppe informazioni?....
```
'Invio le informazioni ad outlook
    Set outApp = CreateObject("Outlook.Application")
    Set outMsg = outApp.CreateItem(olMailItem)
    With outMsg
      .Importance = olImportanceHigh
      .To = Email
      .CC = ""
      .BCC = ""
      .Subject = Oggetto
      .HTMLBody = Corpo & vbNewLine & vbNewLine & Signature ' aggiungo anche la firma al corpo
            
      .Attachments.Add  (qui il percorso del file da  allegare)
    
       'invio la mail con l'allegato
      .Send
   End With
```
Allegati:

25463_dd4d6feb6d6715edc958183ff8cdf2d5.jpg
@Alex
Super Famoso
Iscritto da
feb, 2012
Messaggi:
8752
Re: Inviare email con allegato pdf esterno
03 feb 2019, 13:55
Piuttosto di darne in modo incomprensibile... speriamo che il suo MsOurlook sia configurato ed usato come MailClient....

In ogni caso non si usa mail l'inserimento dei riferimenti nel progetto(EarlyBinding) perché è vincolante.
Meglio suggerire Latebinding.
M
MARMAURO
Utente Attivo
Iscritto da
gen, 2019
Messaggi:
149
Re: Inviare email con allegato pdf esterno
03 feb 2019, 14:16
@Alex ha scritto:
Piuttosto di darne in modo incomprensibile... speriamo che il suo MsOurlook sia configurato ed usato come MailClient....

In ogni caso non si usa mail l'inserimento dei riferimenti nel progetto(EarlyBinding) perché è vincolante.
Meglio suggerire Latebinding.
Concordo con te ... e ti giuro che non voglio fare polemica... Ho solo condiviso la soluzione che io ho applicato per risolvere questo problema...magari a qualcuno può bastare... è vero che vincolato a MSOutlook e che questo deve essere configurato come mail client e questa è una limitazione.
M
MARMAURO
Utente Attivo
Iscritto da
gen, 2019
Messaggi:
149
Re: Inviare email con allegato pdf esterno
03 feb 2019, 15:08
Grazie all'osservazione di @Alex ho anch'io il mio modificato codice... in meglio direi:
Per passare da EarlyBinding a Latebinding
sostituire :
Dim outApp As OUTLOOK.Application =====> diventa Dim outApp As Object
Dim outMsg As MailItem =====> diventa Dim outMsg As Object

Set outApp = CreateObject("Outlook.Application")
Set outMsg = outApp.CreateItem(olMailItem) ====> diventa Set outMsg = outApp.CreateItem(0)

Nei riferimenti togliere la spunta sulla libreria di MSOutlook

gfrullo

Pochi posts

Iscritto da: apr, 2018

Messaggi:: 16

Re: Inviare email con allegato pdf esterno

03 feb 2019, 20:52

Grazie!!
Ho risolto così e funziona.

Private Sub ID_DblClick(Cancel As Integer)
Dim NC As String
NC = Forms![rda_approval]![nomefilerda].Value 'con NC nome del campo NOMEFILE
    Set outApp = CreateObject("Outlook.Application")
    Set outMsg = outApp.CreateItem(olMailItem)
    With outMsg
      .Importance = olImportanceHigh
      .To = "indirizzoemail1"
      .CC = "indirizzoemail2"
      .BCC = ""
      .Subject = NC
      .Attachments.Add (NC)
      .HTMLBody = "testo corpo" & "" & "" & "//__GG"  ' aggiungo anche la firma al corpo
       'invio la mail con l'allegato
      .Send
   End With
End Sub

@Alex
Super Famoso
Iscritto da
feb, 2012
Messaggi:
8752
Re: Inviare email con allegato pdf esterno
03 feb 2019, 21:01
Se Outlook fosse aperto si deve recuperare l'istanza aperta non aprirne una Nuova... usando GetObject e gestendo l'errore 429...
Alla fine di tutti l'istanza va chiusa altrimenti te la trovi nell'elenco dei processi e ne apri uno ogni volta che lo lanci...

MARMAURO

Utente Attivo

Iscritto da: gen, 2019

Messaggi:: 149

Re: Inviare email con allegato pdf esterno

03 feb 2019, 21:42

gfrullo ha scritto:

Grazie!!
Ho risolto così e funziona.

Private Sub ID_DblClick(Cancel As Integer)
Dim NC As String
NC = Forms![rda_approval]![nomefilerda].Value 'con NC nome del campo NOMEFILE
    Set outApp = CreateObject("Outlook.Application")
    Set outMsg = outApp.CreateItem(olMailItem)
    With outMsg
      .Importance = olImportanceHigh
      .To = "indirizzoemail1"
      .CC = "indirizzoemail2"
      .BCC = ""
      .Subject = NC
      .Attachments.Add (NC)
      .HTMLBody = "testo corpo" & "" & "" & "//__GG"  ' aggiungo anche la firma al corpo
       'invio la mail con l'allegato
      .Send
   End With
End Sub

Ottimo.. bene...

visto che mancava un pezzettino di codice (colpa mia) .... metti alla fine ...

Set outApp = Nothing
Set outMsg = Nothing

@Alex
Super Famoso
Iscritto da
feb, 2012
Messaggi:
8752
Re: Inviare email con allegato pdf esterno
03 feb 2019, 21:57
Manca nulla...?
Il quit dell'istanza di Mso...?
Dal momento che la istanti nuova... magari chiudiamola...
M
MARMAURO
Utente Attivo
Iscritto da
gen, 2019
Messaggi:
149
Re: Inviare email con allegato pdf esterno
03 feb 2019, 22:49
@Alex ha scritto:
Manca nulla...?
Il quit dell'istanza di Mso...?
Dal momento che la istanti nuova... magari chiudiamola...
Giusto??
```
outApp.Application.Quit
```
oppure
```
outApp.Quit
```
Sinceramente....evidentemente sbagliando...a me ha sempre funzionato....

Grazie

@Alex

Super Famoso

Iscritto da: feb, 2012

Messaggi:: 8752

Re: Inviare email con allegato pdf esterno

04 feb 2019, 07:41

Come sempre le cose si possono fare in diversi modi... uno di questi è farle bene...!


Function SendMail(.... <parametri vari>...) As Boolean
    On Error GoTo Err_Handler
    Const mcProcName       As String= "SendMail"
    Const mcProcParent      As String = "NomeMaschera"
    Dim olApp   As Object
    Dim olMsg   As Object
    Dim bCrateOpen  As Boolean
    
    Set olApp = GetObject(, "Outlook.Application")
    Set outMsg = outApp.CreateItem(olMailItem)
    
    ....
   SendMail=true
   
 Exit_Here:
    On Error Resume Next
    Set outMsg = Nothing
    
    If bCrateOpen  Then olApp.Quit
    Set olApp = Nothing

    Exit Function

Err_Handler:
    Select Case Err.Number
        Case 429
            Set olApp = CreateObject("Outlook.Application")
            bCrateOpen  = True
            Resume Next
        Case Else
            MsgBox Err.Number & " in " & mcProcParent & vbNewLine & Err.Description, vbCritical, mcProcName
    End Select
    Resume Exit_Here
End Function

MARMAURO

Utente Attivo

Iscritto da: gen, 2019

Messaggi:: 149

Re: Inviare email con allegato pdf esterno

04 feb 2019, 21:00

@Alex ha scritto:

Come sempre le cose si possono fare in diversi modi... uno di questi è farle bene...!


Function SendMail(.... <parametri vari>...) As Boolean
    On Error GoTo Err_Handler
    Const mcProcName       As String= "SendMail"
    Const mcProcParent      As String = "NomeMaschera"
    Dim olApp   As Object
    Dim olMsg   As Object
    Dim bCrateOpen  As Boolean
    
    Set olApp = GetObject(, "Outlook.Application")
    Set outMsg = outApp.CreateItem(olMailItem)
    
    ....
   SendMail=true
   
 Exit_Here:
    On Error Resume Next
    Set outMsg = Nothing
    
    If bCrateOpen  Then olApp.Quit
    Set olApp = Nothing

    Exit Function

Err_Handler:
    Select Case Err.Number
        Case 429
            Set olApp = CreateObject("Outlook.Application")
            bCrateOpen  = True
            Resume Next
        Case Else
            MsgBox Err.Number & " in " & mcProcParent & vbNewLine & Err.Description, vbCritical, mcProcName
    End Select
    Resume Exit_Here
End Function

Troppo avanti per le mie conoscenze... grazie ora studio e poi applico...

Devi accedere o registrarti per scrivere nel forum

14 risposte